4 files changed, 295 insertions, 0 deletions

diff --git a/src/bitstream.nim b/src/bitstream.nim
new file mode 100644
index 0000000..81401ce
--- /dev/null
+++ b/src/bitstream.nim
@@ -0,0 +1,112 @@
+# "à-la-gzip" gzip-like LZSS compressor
+# Copyright (C) 2018  Pacien TRAN-GIRARD
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Affero General Public License as
+# published by the Free Software Foundation, either version 3 of the
+# License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Affero General Public License for more details.
+#
+# You should have received a copy of the GNU Affero General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+import streams
+import integers
+
+# Stream functions
+
+proc newEIO(msg: string): ref IOError =
+  new(result)
+  result.msg = msg
+
+proc read[T](s: Stream, t: typedesc[T]): T =
+  if readData(s, addr(result), sizeof(T)) != sizeof(T):
+    raise newEIO("cannot read from stream")
+
+proc peek[T](s: Stream, t: typedesc[T]): T =
+  if peekData(s, addr(result), sizeof(T)) != sizeof(T):
+    raise newEIO("cannot read from stream")
+
+# Utils
+
+iterator chunks*(totalBitLength: int, chunkType: typedesc[SomeInteger]): tuple[index: int, chunkBitLength: int] =
+  let chunkBitLength = sizeof(chunkType) * wordBitLength
+  let wordCount = totalBitLength div chunkBitLength
+  for i in 0..<(wordCount): yield (i, chunkBitLength)
+  let remainder = totalBitLength mod chunkBitLength
+  if remainder > 0: yield (wordCount, remainder)
+
+# BitStream
+
+type BitStream* = ref object
+  stream: Stream
+  bitOffset: int
+  writeBuffer: uint8
+
+proc bitStream*(stream: Stream): BitStream =
+  BitStream(stream: stream, bitOffset: 0, writeBuffer: 0)
+
+proc flush*(bitStream: BitStream) =
+  if bitStream.bitOffset == 0: return
+  bitStream.stream.write(bitStream.writeBuffer)
+  bitStream.stream.flush()
+  (bitStream.bitOffset, bitStream.writeBuffer) = (0, 0'u8)
+
+proc atEnd*(bitStream: BitStream): bool =
+  bitStream.stream.atEnd()
+
+proc readBits*[T: SomeUnsignedInt](bitStream: BitStream, bits: int, to: typedesc[T]): T =
+  let targetBitLength = sizeof(T) * wordBitLength
+  if bits < 0 or bits > targetBitLength:
+    raise newException(RangeError, "invalid bit length")
+  elif bits == 0:
+    result = 0
+  elif bits < targetBitLength - bitStream.bitOffset:
+    result = bitStream.stream.peek(T) shl (targetBitLength - bits - bitStream.bitOffset) shr (targetBitLength - bits)
+  elif bits == targetBitLength - bitStream.bitOffset:
+    result = bitStream.stream.read(T) shl (targetBitLength - bits - bitStream.bitOffset) shr (targetBitLength - bits)
+  else:
+    let rightBits = targetBitLength - bitStream.bitOffset
+    let leftBits = bits - rightBits
+    let right = bitStream.stream.read(T) shr bitStream.bitOffset
+    let left = bitStream.stream.peek(T) shl (targetBitLength - leftBits) shr (targetBitLength - bits)
+    result = left or right
+  bitStream.bitOffset = (bitStream.bitOffset + bits) mod wordBitLength
+
+proc readBool*(bitStream: BitStream): bool =
+  bitStream.readBits(1, uint8) != 0
+
+proc readSeq*[T: SomeUnsignedInt](bitStream: BitStream, bitLength: int, to: typedesc[T]): tuple[bitLength: int, data: seq[T]] =
+  result = (0, newSeqOfCap[T](bitLength /^ (sizeof(T) * wordBitLength)))
+  for _, chunkBitLength in chunks(bitLength, T):
+    if bitStream.atEnd(): return
+    result.bitLength += chunkBitLength
+    result.data.add(bitStream.readBits(chunkBitLength, T))
+
+proc writeBits*(bitStream: BitStream, bits: int, value: SomeUnsignedInt) =
+  let valueContainerBitLength = sizeof(value) * wordBitLength
+  if bits < 0 or bits > valueContainerBitLength:
+    raise newException(RangeError, "invalid bit length")
+  var bitsToWrite = bits
+  if bitsToWrite + bitStream.bitOffset >= wordBitLength:
+    bitStream.stream.write(truncateToUint8(value shl bitStream.bitOffset) or bitStream.writeBuffer)
+    bitsToWrite -= wordBitLength - bitStream.bitOffset
+    (bitStream.bitOffset, bitStream.writeBuffer) = (0, 0'u8)
+  while bitsToWrite >= wordBitLength:
+    bitStream.stream.write(truncateToUint8(value shr (bits - bitsToWrite)))
+    bitsToWrite -= wordBitLength
+  if bitsToWrite > 0:
+    let left = truncateToUint8((value shl (valueContainerBitLength - bits)) shr (valueContainerBitLength - bitsToWrite))
+    bitStream.writeBuffer = (left shl bitStream.bitOffset) or bitStream.writeBuffer
+    bitStream.bitOffset = (bitStream.bitOffset + bitsToWrite) mod wordBitLength
+
+proc writeBool*(bitStream: BitStream, value: bool) =
+  bitStream.writeBits(1, value.uint8)
+
+proc writeSeq*[T: SomeUnsignedInt](bitStream: BitStream, bitLength: int, data: seq[T]) =
+  for i, chunkBitLength in chunks(bitLength, T):
+    bitStream.writeBits(chunkBitLength, data[i])
diff --git a/src/integers.nim b/src/integers.nim
new file mode 100644
index 0000000..1b9121c
--- /dev/null
+++ b/src/integers.nim
@@ -0,0 +1,24 @@
+# "à-la-gzip" gzip-like LZSS compressor
+# Copyright (C) 2018  Pacien TRAN-GIRARD
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Affero General Public License as
+# published by the Free Software Foundation, either version 3 of the
+# License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Affero General Public License for more details.
+#
+# You should have received a copy of the GNU Affero General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+const wordBitLength* = 8
+const wordBitMask* = 0b1111_1111'u8
+
+proc `/^`*[T: Natural](x, y: T): T =
+  (x + y - 1) div y
+
+proc truncateToUint8*(x: SomeUnsignedInt): uint8 =
+  (x and wordBitMask).uint8
diff --git a/tests/tbitstream.nim b/tests/tbitstream.nim
new file mode 100644
index 0000000..2292049
--- /dev/null
+++ b/tests/tbitstream.nim
@@ -0,0 +1,131 @@
+# "à-la-gzip" gzip-like LZSS compressor
+# Copyright (C) 2018  Pacien TRAN-GIRARD
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Affero General Public License as
+# published by the Free Software Foundation, either version 3 of the
+# License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Affero General Public License for more details.
+#
+# You should have received a copy of the GNU Affero General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+import unittest, streams, sugar, sequtils
+import integers, bitstream
+
+suite "bitstream":
+  test "chunks iterator":
+    check toSeq(chunks(70, uint32)) == @[(0, 32), (1, 32), (2, 6)]
+    check toSeq(chunks(32, uint16)) == @[(0, 16), (1, 16)]
+
+  test "flush":
+    let stream = newStringStream()
+    defer: stream.close()
+    let bitStream = stream.bitStream()
+
+    bitStream.writeBool(true)
+    stream.setPosition(0)
+    expect IOError: discard stream.peekUint8()
+  
+    bitStream.flush()
+    stream.setPosition(0)
+    check stream.readUint8() == 0x01'u8
+    check stream.atEnd()
+
+    bitStream.flush()
+    check stream.atEnd()
+
+  test "readBool":
+    let stream = newStringStream()
+    defer: stream.close()
+    stream.write(0b1001_1111'u8)
+    stream.write(0b0110_0000'u8)
+    stream.setPosition(0)
+    
+    let bitStream = stream.bitStream()
+    check lc[bitStream.readBool() | (_ <- 0..<16), bool] == @[
+      true, true, true, true, true, false, false, true,
+      false, false, false, false, false, true, true, false]
+
+    expect IOError: discard bitStream.readBool()
+    check bitStream.atEnd()
+
+  test "readBits":
+    let stream = newStringStream()
+    defer: stream.close()
+    stream.write(0xF00F'u16)
+    stream.write(0x0FFF'u16)
+    stream.setPosition(0)
+
+    let bitStream = stream.bitStream()
+    check bitStream.readBits(8, uint8) == 0x0F'u8
+    check bitStream.readBits(16, uint16) == 0xFFF0'u16
+    check bitStream.readBits(8, uint8) == 0x0F'u8
+
+    expect RangeError: discard bitStream.readBits(9, uint8)
+    expect IOError: discard bitStream.readBits(16, uint16)
+    check bitStream.atEnd()
+
+  test "readSeq":
+    let stream = newStringStream()
+    defer: stream.close()
+    stream.write(0x0F00_F0FF_F0F0_F0F0'u64)
+    stream.setPosition(0)
+
+    let bitStream = stream.bitStream()
+    check bitStream.readSeq(32, uint16) == (32, @[0xF0F0'u16, 0xF0F0])
+    check bitStream.readSeq(40, uint8) == (32, @[0xFF'u8, 0xF0, 0x00, 0x0F])
+    check bitStream.atEnd()
+
+  test "writeBool":
+    let stream = newStringStream()
+    defer: stream.close()
+
+    let bitStream = stream.bitStream()
+    let booleanValues = @[
+      true, true, true, true, true, false, false, true,
+      false, false, false, false, false, true, true, false,
+      true, true, false, true]
+    for b in booleanValues: bitStream.writeBool(b)
+    bitStream.flush()
+
+    stream.setPosition(0)
+    check stream.readUint8() == 0b1001_1111'u8
+    check stream.readUint8() == 0b0110_0000'u8
+    check stream.readUint8() == 0b0000_1011'u8
+    expect IOError: discard stream.readUint8()
+    check stream.atEnd()
+
+  test "writeBits":
+    let stream = newStringStream()
+    defer: stream.close()